前言

Jenkins， DevOps 技術(shù)棧的核心之一，CI/CD 離不開(kāi)編寫(xiě) Pipeline 腳本，上手 Jenkins ，簡(jiǎn)單查一下文檔，你就應(yīng)該不會(huì)被 agent，stages，step 這類(lèi)關(guān)鍵詞弄懵，也能很快構(gòu)建出 pipeline 的骨架

但是當(dāng)向骨架中填充內(nèi)容的時(shí)候，尤其如何利用環(huán)境變量（系統(tǒng)內(nèi)置 ｜ 自定義），多數(shù)人都會(huì)變得比較混亂，浪費(fèi)很多時(shí)間，本文就幫助大家快速通關(guān)環(huán)境變量

準(zhǔn)備

如果你想一邊閱讀本文，一邊實(shí)踐，但是沒(méi)有 Jenkins 服務(wù)可用，又想快速?lài)L試，可以應(yīng)用 Docker 一個(gè)命令快速搭建 Jenkins 服務(wù)

docker container run --rm -p 8080:8080 -p 50000:50000 --name=jenkins -v $(pwd):/var/jenkins_home jenkins/jenkins

2021 年了，本地沒(méi)有 Docker 說(shuō)不過(guò)去了，過(guò)來(lái)瞧瞧 Docker 系列是否入得了你的法眼？

打開(kāi)瀏覽器輸入：localhost:8080

• 找到終端的臨時(shí)密碼登陸
• 安裝推薦的依賴(lài)
• 創(chuàng)建新的 Pipeline 類(lèi)型的 Item
• 點(diǎn)擊左側(cè) Config，然后在頁(yè)面底部 Pipeline 部分輸入我們接下來(lái)寫(xiě)的腳本進(jìn)行測(cè)試就好了

就是這么簡(jiǎn)單.....

認(rèn)識(shí) Jenkins 環(huán)境變量

Jenkins 環(huán)境變量就是通過(guò) env 關(guān)鍵字暴露出來(lái)的全局變量，可以在 Jenkins 文件的任何位置使用

其實(shí)和你使用的編程語(yǔ)言中的全局變量沒(méi)有實(shí)質(zhì)差別

查看 Jenkins 系統(tǒng)內(nèi)置環(huán)境變量

Jenkins 在系統(tǒng)內(nèi)置了很多環(huán)境變量方便我們快速使用，查看起來(lái)有兩種方式：

方式一：

直接在瀏覽器中訪問(wèn) ${YOUR_JENKINS_HOST}/env-vars.html 頁(yè)面就可以，比如 http://localhost:8080/env-vars.html ，每個(gè)變量的用途寫(xiě)的都很清楚

方式二

通過(guò)執(zhí)行 printenv shell 命令來(lái)獲取：

pipeline {
  agent any

  stages {
    stage("Env Variables") {
      steps {
        sh "printenv"
      }
    }
  }
}

直接 Save - Build, 在終端 log 中你會(huì)看到相應(yīng)的環(huán)境變量，并且可以快速看到他們當(dāng)前的值

通常這兩種方式可以結(jié)合使用

讀取環(huán)境變量

上面我們說(shuō)了 env 是環(huán)境變量的關(guān)鍵字，但是讀取 Jenkins 內(nèi)置的這些環(huán)境變量，env 關(guān)鍵字是可有可無(wú), 但不能沒(méi)了底褲，都要使用 ${xxx} 包圍起來(lái)。以 BUILD_NUMBER 這個(gè)內(nèi)置環(huán)境變量舉例來(lái)說(shuō)明就是這樣滴：

如果你在 Jenkins 文件中使用 shell 命令，使用這些內(nèi)置環(huán)境變量甚至可以不用 {}， 來(lái)看一下：

pipeline {
  agent any

  stages {
    stage("Read Env Variables") {
      steps {
        echo "帶 env 的讀取方式：${env.BUILD_NUMBER}"
        echo "不帶 env 的讀取方式：${BUILD_NUMBER}"
        sh 'echo "shell 中讀取方式 $BUILD_NUMBER"'
      }
    }
  }
}

可以看到結(jié)果是一樣一樣滴，不管有幾種，記住第一種最穩(wěn)妥

內(nèi)置的環(huán)境變量雖好，但也不能完全滿(mǎn)足我們自定義的 pipeline 的執(zhí)行邏輯，所以我們也得知道如何定義以及使用自定義環(huán)境變量

自定義 Jenkins 環(huán)境變量

Jenkins pipeline 分聲明式（Declarative）和 腳本式（imperative）寫(xiě)法，相應(yīng)的環(huán)境變量定義方式也略有不同，歸納起來(lái)有三種方式：

還是看個(gè)實(shí)際例子吧：

pipeline {
  agent any

  environment {
    FOO = "bar"
  }

  stages {
    stage("Custom Env Variables") {
      environment {
        NAME = "RGYB"
      }

      steps {
        echo "FOO = ${env.FOO}"
        echo "NAME = ${env.NAME}"

        script {
          env.SCRIPT_VARIABLE = "Thumb Up"
        }

        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}"

        withEnv(["WITH_ENV_VAR=Come On"]) {
          echo "WITH_ENV_VAR = ${env.WITH_ENV_VAR}"
        }
      }
    }
  }
}

來(lái)看運(yùn)行結(jié)果：

注意：withEnv(["WITH_ENV_VAR=Come On"]) {} 這里的 = 號(hào)兩側(cè)不能有空格，必須是 key=value 的形式

一個(gè)完整的 pipeline 通常會(huì)有很多個(gè) stage，環(huán)境變量在不同的 stage 有不同的值是很常見(jiàn)的，知道如何設(shè)置以及讀取環(huán)境變量后，我們還得知道如何重寫(xiě)環(huán)境變量

重寫(xiě) Jenkins 環(huán)境變量

Jenkins 讓人相對(duì)困惑最多的地方就是重寫(xiě)環(huán)境變量，但是只要記住下面這三條規(guī)則，就可以搞定一切了

• withEnv(["WITH_ENV_VAR=Come On"]) {} 內(nèi)置函數(shù)的這種寫(xiě)法，可以重寫(xiě)任意環(huán)境變量
• 定義在 environment {} 的環(huán)境變量不能被腳本式定義的環(huán)境變量（env.key="value"）重寫(xiě)
• 腳本式環(huán)境變量只能重寫(xiě)腳本式環(huán)境變量

這三點(diǎn)是硬規(guī)則，沒(méi)涵蓋在這 3 點(diǎn)規(guī)則之內(nèi)的也就是被允許的了

三條規(guī)則就有點(diǎn)讓人頭大了，農(nóng)夫選豆種，舉例為證吧

pipeline {
  agent any

  environment {
    FOO = "你當(dāng)像鳥(niǎo)飛往你的山"
    NAME = "Tan"
  }

  stages {
    stage("Env Variables") {
      environment {
       	// 會(huì)重寫(xiě)第 6 行 變量
        NAME = "RGYB" 
       	// 會(huì)重寫(xiě)系統(tǒng)內(nèi)置的環(huán)境變量 BUILD_NUMBER
        BUILD_NUMBER = "10" 
      }

      steps {
       	// 應(yīng)該打印出 "FOO = 你當(dāng)像鳥(niǎo)飛往你的山"
        echo "FOO = ${env.FOO}" 
       	// 應(yīng)該打印出 "NAME = RGYB"
        echo "NAME = ${env.NAME}" 
       	// 應(yīng)該打印出 "BUILD_NUMBER = 10"
        echo "BUILD_NUMBER = ${env.BUILD_NUMBER}" 

        script {
         	// 腳本式創(chuàng)建一個(gè)環(huán)境變量
          env.SCRIPT_VARIABLE = "1" 
        }
      }
    }

    stage("Override Variables") {
      steps {
        script {
         	// 這里的 FOO 不會(huì)被重寫(xiě)，違背 Rule No.2
          env.FOO = "Tara"
         	// SCRIPT_VARIABLE 變量會(huì)被重寫(xiě)，符合 Rule No.3
          env.SCRIPT_VARIABLE = "2" 
        }

       	// FOO 在第 37 行重寫(xiě)失敗，還會(huì)打印出 "FOO = 你當(dāng)像鳥(niǎo)飛往你的山"
        echo "FOO = ${env.FOO}" 
       	// 會(huì)打印出 "SCRIPT_VARIABLE = 2"
        echo "SCRIPT_VARIABLE = ${env.SCRIPT_VARIABLE}" 

       	// FOO 會(huì)被重寫(xiě)，符合 Rule No.1
        withEnv(["FOO=Educated"]) { 
         	// 應(yīng)該打印 "FOO = Educated"
          echo "FOO = ${env.FOO}" 
        }

       	// 道理同上
        withEnv(["BUILD_NUMBER=15"]) {
         	// 應(yīng)該打印出 "BUILD_NUMBER = 15"
          echo "BUILD_NUMBER = ${env.BUILD_NUMBER}"
        }
      }
    }
  }
}

來(lái)驗(yàn)證一下結(jié)果吧

看到這，基本的設(shè)置應(yīng)該就沒(méi)有什么問(wèn)題了，相信你也發(fā)現(xiàn)了，Jenkins 設(shè)置環(huán)境變量和編程語(yǔ)言的那種設(shè)置環(huán)境變量還是略有不同的，后者可以將變量賦值為對(duì)象，但 Jenkins 就不行，因?yàn)樵?Jenkins 文件中，所有設(shè)置的值都會(huì)被當(dāng)成 String， 難道沒(méi)辦法應(yīng)用 Boolean 值嗎？

Jenkins 中使用 Boolean 值

如果設(shè)置一個(gè)變量為 false ，Jenkins 就會(huì)將其轉(zhuǎn)換為 "false", 如果想使用 Boolean 來(lái)做條件判斷，必須要調(diào)用 toBoolean() 方法做轉(zhuǎn)換

pipeline {
  agent any

  environment {
    IS_BOOLEAN = false
  }

  stages {
    stage("Env Variables") {
      steps {
        script {
         	// Hello 會(huì)被打印出來(lái)，因?yàn)榉强兆址紩?huì)被認(rèn)為是 Boolean.True
          if (env.IS_BOOLEAN) {
            echo "Hello"
          }

         	// 真正的 Boolean 比較
          if (env.IS_BOOLEAN.toBoolean() == false) {
            echo "日拱一兵"
          }
         
         	// 真正的 Boolean 
          if (!env.IS_BOOLEAN.toBoolean()) {
            echo "RGYB"
          }
        }
      }
    }
  }
}

來(lái)看運(yùn)行結(jié)果：

如果你寫(xiě)過(guò) Pipeline，你一定會(huì)知道，寫(xiě) Pipeline 是離不開(kāi)寫(xiě) shell 的，有些時(shí)候，需要將 shell 的執(zhí)行結(jié)果賦值給環(huán)境變量，Jenkins 也有方法支持

Shell 結(jié)果賦值給環(huán)境變量

實(shí)現(xiàn)這種方式很簡(jiǎn)單，只需要記住一個(gè)格式：sh(script: 'cmd', returnStdout:true)

pipeline {
  agent any

  environment {
   	// 使用 trim() 去掉結(jié)果中的空格
    LS_RESULT = "${sh(script:'ls -lah', returnStdout: true).trim()}"
  }

  stages {
    stage("Env Variables") {
      steps {
        echo "LS_RESULT = ${env.LS_RESULT}"
      }
    }
  }
}

總結(jié)

關(guān)于 Jenkins 環(huán)境變量，了解這些基本上就滿(mǎn)足絕大多數(shù)應(yīng)用場(chǎng)景了，當(dāng)再遇到環(huán)境變量問(wèn)題時(shí)，可以回過(guò)來(lái)翻看一下了，有解決的困惑嗎？

到此這篇關(guān)于10分鐘搞定讓你困惑的 Jenkins 環(huán)境變量的文章就介紹到這了,更多相關(guān)Jenkins 環(huán)境變量?jī)?nèi)容請(qǐng)搜索腳本之家以前的文章或繼續(xù)瀏覽下面的相關(guān)文章希望大家以后多多支持腳本之家！